InputMode:=Word

PrecisionDigits:=64

"Load the symbolic integration table for Carlson's elliptic integrals."

"The table was generated using equation 3.5 in the paper"

"Toward Symbolic Integration of Elliptic Integrals."

"This equation is DERIVE function R35(q,j,h,a,b,e) in c1998.mth."

LOAD("c1999.mth")

"This is an example of an integral that occurs in particle physics."

int1:=INT(SQRT((d-t)*(c-t)*(t-b)*(t-a))/t,t,b,c)

"It is a special complete case of I(1,1,1,1,-1)."

"For the integral to be well defined, one assumes a<b<c<d."

"It is symmetric in some peculiar combinations of a,b,c,d."

"an, bn, cn, dn are random values to test the algorithms."

[an:=65/168,bn:=29/47,cn:=116/129,dn:=147/82]

"Substitute this values in the integral."

int2:=SUBST(int1,[a,b,c,d],[an,bn,cn,dn])

"refint is a check value calulated to 64 digits."

"Digits:=64"

"evalf(sqrt(580027)*int(sqrt(147-82*t)*sqrt(116-129*t)*sqrt(47*t-29)*sqrt(168*~
t-65)/t,t=29/47...116/129)/6960324);"

refint:=0.02541924425179893774029322781478333663469179657918908272749047018

"Do numeric integration to show this check value is correct."

APPROX(int2-refint,16)

"Now do partial fraction expansion using the equation 2.19 in the paper"

"Toward Symbolic Integration of Elliptic Integrals."

"The DERIVE function used is D219A(i,m,n,h) in c1999.mth."

"mm=m in the elliptic integral I(m) defined in equation 2.17."

mm:=[1,1,1,1,-1]

"al and am are a in equation 2.17."

al:=[d,c,-b,-a,0]

am:=[dn,cn,-bn,-an,0]

"bm is b in equation 2.17."

bm:=[-1,-1,1,1,1]

"In equation 2.19 set i=1, n=5, and h=4."

"The meaning of n and h are in defined in equation 2.17."

v1:=D219A(1,mm,5,4)

"This is the symbolic result for a general case where [a1, a2, a3, a4, a5]"

"and [b1, b2, b3, b4, b5] are not known."

"The definition of d12 is in the equations 2.5, so d12=a1*b2-a2*b1."

"The DERIVE function D219C(v1,al,bm) substitutes the known values of al and bm"

"into the expression v1. D219C(v,a,b) is in c1999.mth."

v2:=D219C(v1,al,bm)

"AA(e1+e2+e3+e4) and AA(e2+e3+e4) are defined in equation 3.1."

"The DERIVE function AF(m,h,n,a,b,x,y) is in c1998.mth."

v3:=AF([0,1,1,1],4,4,al,bm,x,y)

AA(e2+e3+e4)=LIM(LIM(v3,x,c),y,b)

v4:=AF([1,1,1,1],4,4,al,bm,x,y)

AA(e1+e2+e3+e4)=LIM(LIM(v4,x,c),y,b)

"Substitute the values of AA(e1+e2+e3+e4) and AA(e2+e3+e4) into the expression~
 v2."

aaa:=[[e1+e2+e3+e4,0],[e2+e3+e4,0]]

AA(v):='(SELECT(k SUB 1=v,k,aaa)) SUB 1 SUB 2

v2

"This is the symbolic results in terms of basic integrals I(-e1), I(e1), I(-e5~
)"

"and I(e0). e1, e5, and e0 are defined in equation 2.18."

"To check the results we use numerical values an, bn, cn, dn."

v5:=SUBST(v2,[a,b,c,d],[an,bn,cn,dn])

"Find the basic integrals in the table."

IS([IA(-e1),IA(e1),IA(-e5),IA(0)],4)

"The DERIVE functions I428(a,b,x,y), I429(a,b,x,y), I427(a,b,x,y), and "

"I414(a,b,x,y) are in c1998.mth. They are defined by equation 4.28, 4.29, 4.27~
, and"

"4.14 in the paper. There is a revision to these equations in a latter paper"

"Reduction Theorems for Elliptic Integrands with Square Root of two Quadratic ~
Factors."

"Evaluate the basic integrals."

bi1:=APPROX([I428(am,bm,cn,bn),I429(am,bm,cn,bn),I427(am,bm,cn,bn),I414(am,bm~
,cn,bn)],128)

"The value of I(e1) should be real so split the integral for another try."

bi:=[bi1 SUB 1,APPROX(I429(am,bm,(bn+cn)/2,bn)+I429(am,bm,cn,(bn+cn)/2),128),~
bi1 SUB 3,bi1 SUB 4]

"Now subsitute the values of the basic integrals into the expression v5 and"

"compare that to the check value."

iaa:=[[-e1,bi SUB 1],[e1,bi SUB 2],[-e5,bi SUB 3],[0,bi SUB 4]]

IA(v):='(SELECT(k SUB 1=v,k,iaa)) SUB 1 SUB 2

APPROX(v5-refint)

"This result matches the check value to 63 places."